Q100242: விண்டோஸிற்கான லாஞ்சர் ஸ்கிரிப்டைப் பயன்படுத்தி மூன்றாம் தரப்பு ரெண்டரர் செருகுநிரல்களுடன் Katana தொடங்குவது எப்படி

Elisabeth Wetchy

Updated : August 30, 2024 15:11

Created : December 09, 2016 12:08

சுருக்கம்

Katana தொடங்கவும், பல்வேறு ரெண்டரர் செருகுநிரல்களுடன் பணிபுரியவும், சில சூழல் மாறிகள் சரியாக அமைக்கப்பட்டிருப்பதை உறுதிசெய்ய வேண்டும். தற்போது இந்த சூழல் மாறிகளை நிர்வகிப்பதற்கான எளிதான வழி, Katana தொடங்க லாஞ்சர் பேட்ச் ஸ்கிரிப்டைப் பயன்படுத்துவதாகும்.

இந்தக் கட்டுரையானது பல்வேறு ரெண்டரர் செருகுநிரல்களை உள்ளடக்கிய ஒரு எடுத்துக்காட்டு ஸ்கிரிப்டை கீழே வழங்குகிறது, மேலும் இது பயன்பாட்டிற்கு தயாராக உள்ளது. இது நன்கு கருத்துரைக்கப்பட்டுள்ளது, மேலும் உங்கள் பணிப்பாய்வுகளில் உங்களுக்குத் தேவையில்லாத ரெண்டரர் செருகுநிரல்களுக்கான குறிப்புகளை மட்டும் நீக்க வேண்டும்.

குறிப்பு: இந்த ஸ்கிரிப்ட்டில் பயன்படுத்தப்படும் பல்வேறு கூறுகளுக்கு உங்கள் பாதைகள் வேறுபட்டால், அந்த பாதைகளை உங்கள் கணினியில் சரியான இடத்திற்கு புதுப்பிக்க வேண்டும்.

நீங்கள் இன்னும் Katana விண்டோஸில் நிறுவி உரிமம் பெறவில்லை என்றால், விண்டோஸ் பயனர் கையேட்டில் நிறுவுவதைப் பார்க்கவும்.

துவக்கி ஸ்கிரிப்ட்டை கட்டமைக்கிறது

இந்த ஸ்கிரிப்டை எவ்வாறு மாற்றுவது மற்றும் பயன்படுத்துவது என்பதற்கான வழிமுறைகளுக்கு, இந்தப் படிகளைப் பின்பற்றவும்:

கீழே உள்ள ஸ்கிரிப்ட்டின் உள்ளடக்கங்களை நகலெடுத்து ஒட்டவும் (எடுத்துக்காட்டு லாஞ்சர் பேட்ச் ஸ்கிரிப்ட் ) உரை திருத்தியில் ஒட்டவும், எடுத்துக்காட்டாக நோட்பேட் .
ஒரு எடுத்துக்காட்டு கோப்பும் இணைக்கப்பட்டுள்ளது, எனவே இணைக்கப்பட்ட தொகுதி ஸ்கிரிப்டைப் பதிவிறக்கவும். .bat கோப்பைத் திருத்த, கோப்பில் வலது கிளிக் செய்து 'Edit' என்பதைத் தேர்ந்தெடுக்கவும்.
ஸ்கிரிப்டை கவனமாகப் படிக்கவும், குறிப்பிட்ட பாதைகள் உங்கள் கணினியில் உள்ளதா எனச் சரிபார்க்கவும். இல்லையெனில், சரியான இடங்களைச் சுட்டிக்காட்டும் வகையில் அவற்றைப் புதுப்பிக்கவும்.
நீங்கள் பயன்படுத்தாத கருவிகளுக்கான குறிப்பிட்ட பிரிவுகளை நீக்கவும், எடுத்துக்காட்டாக ரெண்டரர்கள் அல்லது தனிப்பயன் ஸ்கிரிப்ட்கள்.
கோப்பை Katana 6.0v2.bat ஆக சேமித்து அதை மூடவும்.
இப்போது .bat கோப்பை இருமுறை கிளிக் செய்யவும் அல்லது வலது கிளிக் செய்யவும் > ஓபன் கட்டளைகளை இயக்க வேண்டும் மற்றும் தேவையான அனைத்து சூழல் மாறிகள் அமைக்கப்பட்டுள்ள Katana துவக்க வேண்டும்.

அவை சரியாக அமைக்கப்பட்டதா என்பதை நீங்கள் சரிபார்க்கலாம், எடுத்துக்காட்டாக, பைதான் தாவலில் இந்த கட்டளைகளை இயக்குவதன் மூலம்:
```
import os
print(os.environ['KATANA_RESOURCES'])
```
லாஞ்சர் ஸ்கிரிப்ட்டில் நீங்கள் KATANA _RESOURCES இல் சேர்த்த பாதைகளை இது அச்சிட வேண்டும்.
டெஸ்க்டாப் ஐகானைக் கிளிக் செய்து Katana தொடங்க நீங்கள் விரும்பினால், பின்வரும் வழியில் இதைச் சேர்க்கலாம்:

.bat கோப்பில் வலது கிளிக் செய்யவும் > குறுக்குவழியை உருவாக்கவும்.
உங்கள் டெஸ்க்டாப்பில் உருவாக்கப்பட்ட குறுக்குவழியை வைக்கவும்.
குறுக்குவழி > பண்புகள் > குறுக்குவழி தாவல் > ஐகானை மாற்று...
நீங்கள் இப்போது .bat கோப்பில் ஐகான்கள் இல்லை என்ற எச்சரிக்கையைக் காணலாம். சரி என்பதைக் கிளிக் செய்து, வேறு இடத்திலிருந்து ஐகானைத் தேர்ந்தெடுக்கும் விருப்பத்தைப் பெறுவீர்கள்.
உலாவுக ... என்பதைக் கிளிக் செய்து, உங்கள் Katana நிறுவல் கோப்பகத்தில் (KATANA_ROOT) உலாவவும். WindowsIcon.ico கோப்பைத் தேர்ந்தெடுத்து திற என்பதைக் கிளிக் செய்யவும். மாற்று ஐகான் உரையாடலை மூட சரி என்பதைக் கிளிக் செய்து, பண்புகள் சாளரத்தை மூட சரி என்பதைக் கிளிக் செய்யவும்.

உங்கள் டெஸ்க்டாப்பில் Katana ஐகானைக் காட்டும் Katana லாஞ்சர் ஸ்கிரிப்ட் ஷார்ட்கட் இப்போது உங்களிடம் இருக்க வேண்டும்.

KATANA லாஞ்சர் ஸ்கிரிப்ட்

முக்கிய KATANA சூழல் மாறிகள்

KATANA _ROOT உங்கள் Katana நிறுவல் கோப்பகத்தை சுட்டிக்காட்ட வேண்டும்.
PATH என்பது இயங்கக்கூடிய நிரல்கள் அமைந்துள்ள கோப்பகங்களைக் குறிப்பிடும் விண்டோஸ் சிஸ்டம் மாறியாகும்.
KATANA _RESOURCES ஆனது செருகுநிரல்கள் மற்றும் பிற தனிப்பயனாக்கங்களைத் தேடுவதற்கான பாதைகளின் பட்டியலை வழங்குகிறது, எடுத்துக்காட்டாக ஷேடர்கள். மேலும் தகவலுக்கு, Katana வளங்கள் நிறுவல் வழிகாட்டியைப் பார்க்கவும்.

சில தொகுதி கோப்பு கட்டளைகள் விளக்கப்பட்டுள்ளன

rem ஒரு கருத்தைக் குறிக்கிறது; விண்டோஸ் ஸ்கிரிப்டை இயக்கும் போது இந்த கட்டளையுடன் தொடங்கும் வரிகள் புறக்கணிக்கப்படும்.
@echo off கட்டளை வரியில் செயல்படுத்தப்பட்ட கட்டளைகளின் காட்சியை முடக்குகிறது.
set என்பது சூழல் மாறியை அமைப்பதற்கான கட்டளை. பல பாதைகளை அரைப்புள்ளி ( ; ) மூலம் பிரிக்கலாம் .

இறுதி வரி, "%KATANA_ROOT%\bin\katanaBin.exe" , Katana இயங்கக்கூடியது. தொகுதி கோப்பு இந்த வரியை அடைந்ததும், Katana செயல்படுத்தப்படும் கட்டளைகளை எதிரொலிக்கும் கட்டளை வரியில் தோன்றும்.

உதாரணம் துவக்கி தொகுதி ஸ்கிரிப்ட்

@echo off
rem --------------------------------------------
rem -------- How to use this script ------------
rem --------------------------------------------

rem -- The KATANA Specific section shows some examples for how you can use the KATANA _RESOURCES environment variable --

rem -- KATANA _ROOT should point to your Katana installation directory. --
rem -- KATANA _RESOURCES drives what gets loaded at startup for KATANA . --
rem -- This is how you load tools and plug-ins, both custom and non-custom ones like commercial renderer plug-ins --
rem -- DEFAULT_RENDERER is the environment variable that drives which renderer plug-in is expected by default in a Renderexporttings node. --

rem -- Delete the settings for the renderers that you do not have installed or do not want to use at the same time. --
rem -- The different renderer plug-ins' requirements for environment variables may change. --
rem -- Please refer to the installation instructions for each particular render plug-in for the most up to date information --


rem --------------------------------------------
rem ------------ KATANA Specific ---------------
rem https://learn.foundry.com/ katana /dev-guide/EnvironmentVariables.html
rem --------------------------------------------

set "KATANA_TAGLINE=Foundry Support"

rem -- Define the install location for KATANA --
set "KATANA_ROOT=C:\Program Files\Katana6.0v2"

rem -- Make the example projects like the PyMock asset plugins available in KATANA
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%KATANA_ROOT%\plugins\Resources\Examples"


rem !!!!!!!!!!!!! Delete the tools you do not use from the section below !!!!!!!!!!!!! 


rem --------------------------------------------
rem ----------- 3Delight Specific --------------
rem https://www.3delight.com/documentation/display/3DFK/Installation
rem --------------------------------------------

set "DEFAULT_RENDERER=dl"

rem -- Location of where the main 3Delight package is installed --
set "DELIGHT=C:\Program Files\3Delight"

rem -- The 3Delight bin folder is needed in PATH  --
set "PATH=%PATH%;%DELIGHT%\bin"

rem -- Location of the 3Delight for KATANA plug-in --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%DELIGHT%\3DelightForKatana"


rem --------------------------------------------
rem ------------- Arnold Specific --------------
rem https://help.autodesk.com/view/ARNOL/ENU/?guid=arnold_for_katana_getting_started_ka_Installation_html
rem --------------------------------------------

set "DEFAULT_RENDERER=arnold"

rem -- Where you have installed the KtoA plug-in --
set "KTOA_HOME=C:\Program Files\ktoa\ktoa-4.2.2.1-kat6.0-windows"

rem -- The KtoA bin folder is needed in PATH --
set "PATH=%PATH%;%KTOA_HOME%\bin"

rem -- This is how to load the KtoA plug-in --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%KTOA_HOME%"


rem --------------------------------------------
rem --------- RenderMan 25 Specific ------------
rem https://rmanwiki.pixar.com/display/RFK25/Configuring+Katana
rem --------------------------------------------

set "DEFAULT_RENDERER=prman"

rem -- Location of the RenderMan Pro Server installation --
set "RMANTREE=C:\Program Files\Pixar\RenderManProServer-25.1"

rem -- Location of the PRman plugin for KATANA --
set "RFKTREE=C:\Program Files\Pixar\RenderManForKatana-25.1\plugins\katana6.0"

rem -- This is what is required to load the RfK plugin --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%RFKTREE%"

rem -- This is a workaround to prevent ImportError with Katana Queue --
set "PATH=%PATH%;%KATANA_ROOT%\bin"

rem --------------------------------------------
rem ----------- Redshift Specific --------------
rem C:\ProgramData\Redshift\Plugins\Katana\6.0v1\launchRedshift4Katana.bat
rem --------------------------------------------

set "DEFAULT_RENDERER=redshift"

rem -- Location of the RedShift bin folder --
set "REDSHIFT_HOME=C:\ProgramData\Redshift\bin"

rem -- Location of the RedShift plugin for KATANA --
set "REDSHIFT4KATANA_HOME=C:\ProgramData\Redshift\Plugins\Katana\6.0v1"

rem -- This is what is required to load the RedshiftForKatana plugin --
set "PATH=%PATH%;%REDSHIFT_HOME%"
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%REDSHIFT4KATANA_HOME%"

rem !!!!!!!!!!!!! Stop deleting parts of the script. Leave the rest of this script alone !!!!!!!!!!!!!


rem --------------------------------------------
rem --------------- Start Katana ---------------
rem https://learn.foundry.com/ katana /Content/tg/launch_modes/ katana _launch_modes.html
rem --------------------------------------------
"%KATANA_ROOT%\bin\katanaBin.exe"

Katana தொடங்குதல் மற்றும் பல்வேறு வெளியீட்டு முறைகளைப் பற்றி மேலும் படிக்க, Katana ஆவணப்படுத்தலின் விண்டோஸில் தொடங்குதல் பகுதியைப் பார்க்கவும்.

இணைப்புகள்

We're sorry to hear that

Please tell us why