Q100242: Windows용 런처 스크립트를 사용하여 타사 렌더러 플러그인으로 Katana 시작하는 방법

요약

Katana 시작하고 사용 가능한 다양한 렌더러 플러그인을 사용하려면 몇 가지 환경 변수가 올바르게 설정되었는지 확인해야 합니다. 현재 이러한 환경 변수를 관리하는 가장 쉬운 방법은 시작 관리자 배치 스크립트를 사용하여 Katana 시작하는 것입니다.

이 문서에서는 다양한 렌더러 플러그인을 모두 다루고 바로 사용할 수 있는 예제 스크립트를 아래에 제공합니다. 주석이 잘 설명되어 있으며 작업 흐름에 필요하지 않은 렌더러 플러그인에 대한 참조만 삭제하면 됩니다.

참고: 이 스크립트에 사용된 다양한 구성 요소에 대한 경로가 다른 경우 해당 경로를 시스템의 올바른 위치로 업데이트해야 합니다.

아직 Windows에 Katana 설치하고 라이센스를 부여하지 않은 경우 Windows에 설치 사용 설명서를 참조하십시오.

런처 스크립트 구성

이 스크립트를 수정하고 사용하는 방법에 대한 지침을 보려면 다음 단계를 따르세요.

1. 아래 스크립트(런처 배치 스크립트 예 )의 내용을 복사하여 텍스트 편집기(예: 메모장 ) 에 붙여넣습니다.
   예제 파일도 첨부되어 있으므로 첨부된 배치 스크립트를 다운로드하세요. .bat 파일을 편집하려면 파일을 마우스 오른쪽 버튼으로 클릭하고 '편집'을 선택하세요.
2. 스크립트를 주의 깊게 읽고 지정된 경로가 컴퓨터에서 동일한지 확인하세요. 그렇지 않은 경우 올바른 위치를 가리키도록 업데이트하세요.
3. 사용하지 않는 도구(예: 렌더러 또는 사용자 정의 스크립트)와 관련된 섹션을 삭제하십시오.
4. 파일을 Katana 6.0v2.bat 로 저장하고 닫습니다.
5. 이제 .bat 파일을 두 번 클릭하거나 마우스 오른쪽 버튼을 클릭하고 > 열기 를 클릭 하면 명령이 실행되고 필요한 모든 환경 변수가 설정된 Katana 시작됩니다.
   
   예를 들어 Python 탭에서 다음 명령을 실행하여 올바르게 설정되었는지 확인할 수 있습니다.
   

   import os
   print(os.environ['KATANA_RESOURCES'])

   
   그러면 실행 프로그램 스크립트의 KATANA _RESOURCES에 추가한 경로가 인쇄됩니다.
6. 바탕 화면 아이콘을 클릭하여 Katana 실행하려면 다음과 같은 방법으로 추가할 수 있습니다.

• .bat 파일을 마우스 오른쪽 버튼으로 클릭하고 바로가기 만들기를 클릭합니다.
• 생성된 바로가기를 바탕화면에 놓습니다.
• 바로가기 우클릭 > 속성 > 바로가기 탭 > 아이콘 변경…
• 이제 .bat 파일에 아이콘이 없다는 경고가 표시될 수 있습니다. 확인을 클릭하면 다른 위치에서 아이콘을 선택할 수 있는 옵션이 표시됩니다.
• 찾아보기 ...를 클릭하고 Katana 설치 디렉터리(KATANA_ROOT)를 찾습니다. WindowsIcon.ico 파일을 선택하고 열기를 클릭합니다. 확인을 클릭하여 아이콘 변경 대화 상자를 닫고 확인을 클릭하여 속성 창을 닫습니다.
  
  이제 바탕 화면에 Katana 아이콘을 표시하는 Katana 실행기 스크립트 바로 가기가 생겼습니다.

KATANA 런처 스크립트

주요 KATANA 환경 변수

KATANA _ROOT는 Katana 설치 디렉터리를 가리켜야 합니다.
PATH 는 실행 가능한 프로그램이 있는 디렉터리를 지정하는 Windows 시스템 변수입니다.
KATANA _RESOURCES는 플러그인 및 기타 사용자 정의(예: 셰이더)를 찾을 경로 목록을 제공합니다. 자세한 내용은 Katana 리소스 설치 가이드를 참조하세요.

일부 배치 파일 명령 설명

rem은 주석을 표시합니다. Windows에서 스크립트를 실행할 때 이 명령으로 시작하는 줄은 무시됩니다.
@echo off는 명령 프롬프트에 실행된 명령이 표시되지 않도록 합니다.
set은 환경 변수를 설정하는 명령입니다. 여러 경로는 세미콜론( ; )으로 구분할 수 있습니다.

마지막 줄인 "%KATANA_ROOT%\bin\katanaBin.exe" 는 Katana 실행 파일을 실행합니다. 배치 파일이 이 줄에 도달하면 Katana 가 실행하는 명령을 반영하는 명령 프롬프트가 나타납니다.

런처 배치 스크립트 예시

@echo off
rem --------------------------------------------
rem -------- How to use this script ------------
rem --------------------------------------------

rem -- The KATANA Specific section shows some examples for how you can use the KATANA _RESOURCES environment variable --

rem -- KATANA _ROOT should point to your Katana installation directory. --
rem -- KATANA _RESOURCES drives what gets loaded at startup for KATANA . --
rem -- This is how you load tools and plug-ins, both custom and non-custom ones like commercial renderer plug-ins --
rem -- DEFAULT_RENDERER is the environment variable that drives which renderer plug-in is expected by default in a Renderexporttings node. --

rem -- Delete the settings for the renderers that you do not have installed or do not want to use at the same time. --
rem -- The different renderer plug-ins' requirements for environment variables may change. --
rem -- Please refer to the installation instructions for each particular render plug-in for the most up to date information --


rem --------------------------------------------
rem ------------ KATANA Specific ---------------
rem https://learn.foundry.com/ katana /dev-guide/EnvironmentVariables.html
rem --------------------------------------------

set "KATANA_TAGLINE=Foundry Support"

rem -- Define the install location for KATANA --
set "KATANA_ROOT=C:\Program Files\Katana6.0v2"

rem -- Make the example projects like the PyMock asset plugins available in KATANA
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%KATANA_ROOT%\plugins\Resources\Examples"


rem !!!!!!!!!!!!! Delete the tools you do not use from the section below !!!!!!!!!!!!! 


rem --------------------------------------------
rem ----------- 3Delight Specific --------------
rem https://www.3delight.com/documentation/display/3DFK/Installation
rem --------------------------------------------

set "DEFAULT_RENDERER=dl"

rem -- Location of where the main 3Delight package is installed --
set "DELIGHT=C:\Program Files\3Delight"

rem -- The 3Delight bin folder is needed in PATH  --
set "PATH=%PATH%;%DELIGHT%\bin"

rem -- Location of the 3Delight for KATANA plug-in --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%DELIGHT%\3DelightForKatana"


rem --------------------------------------------
rem ------------- Arnold Specific --------------
rem https://help.autodesk.com/view/ARNOL/ENU/?guid=arnold_for_katana_getting_started_ka_Installation_html
rem --------------------------------------------

set "DEFAULT_RENDERER=arnold"

rem -- Where you have installed the KtoA plug-in --
set "KTOA_HOME=C:\Program Files\ktoa\ktoa-4.2.2.1-kat6.0-windows"

rem -- The KtoA bin folder is needed in PATH --
set "PATH=%PATH%;%KTOA_HOME%\bin"

rem -- This is how to load the KtoA plug-in --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%KTOA_HOME%"


rem --------------------------------------------
rem --------- RenderMan 25 Specific ------------
rem https://rmanwiki.pixar.com/display/RFK25/Configuring+Katana
rem --------------------------------------------

set "DEFAULT_RENDERER=prman"

rem -- Location of the RenderMan Pro Server installation --
set "RMANTREE=C:\Program Files\Pixar\RenderManProServer-25.1"

rem -- Location of the PRman plugin for KATANA --
set "RFKTREE=C:\Program Files\Pixar\RenderManForKatana-25.1\plugins\katana6.0"

rem -- This is what is required to load the RfK plugin --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%RFKTREE%"

rem -- This is a workaround to prevent ImportError with Katana Queue --
set "PATH=%PATH%;%KATANA_ROOT%\bin"

rem --------------------------------------------
rem ----------- Redshift Specific --------------
rem C:\ProgramData\Redshift\Plugins\Katana\6.0v1\launchRedshift4Katana.bat
rem --------------------------------------------

set "DEFAULT_RENDERER=redshift"

rem -- Location of the RedShift bin folder --
set "REDSHIFT_HOME=C:\ProgramData\Redshift\bin"

rem -- Location of the RedShift plugin for KATANA --
set "REDSHIFT4KATANA_HOME=C:\ProgramData\Redshift\Plugins\Katana\6.0v1"

rem -- This is what is required to load the RedshiftForKatana plugin --
set "PATH=%PATH%;%REDSHIFT_HOME%"
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%REDSHIFT4KATANA_HOME%"

rem !!!!!!!!!!!!! Stop deleting parts of the script. Leave the rest of this script alone !!!!!!!!!!!!!


rem --------------------------------------------
rem --------------- Start Katana ---------------
rem https://learn.foundry.com/ katana /Content/tg/launch_modes/ katana _launch_modes.html
rem --------------------------------------------
"%KATANA_ROOT%\bin\katanaBin.exe"

Katana 실행 및 사용 가능한 다양한 실행 모드에 대한 자세한 내용은 Katana 설명서의 Windows에서 실행 섹션을 참조하세요.

첨부 파일