Q100242: विंडोज़ के लिए लॉन्चर स्क्रिप्ट का उपयोग करके थर्ड-पार्टी रेंडरर प्लगइन्स के साथ Katana कैसे लॉन्च करें

KATANA लॉन्चर स्क्रिप्ट शब्दावली

Katana सफलतापूर्वक लॉन्च करने के लिए प्रत्येक लॉन्चर स्क्रिप्ट को निम्नलिखित पर्यावरण चर की आवश्यकता होगी। आपकी सुविधा के लिए नीचे उनके प्राथमिक कार्य के साथ चर दिए गए हैं।

आपकी सुविधा के लिए निम्नलिखित लॉन्चर बैच स्क्रिप्ट में प्रयुक्त कुछ सामान्य बैच कमांड और उनके स्पष्टीकरण नीचे दिए गए हैं।

लॉन्चर स्क्रिप्ट को कॉन्फ़िगर करना

इस स्क्रिप्ट को संशोधित करने और उपयोग करने के निर्देशों के लिए कृपया इन चरणों का पालन करें:

1. नीचे दी गई स्क्रिप्ट में से किसी एक की सामग्री को कॉपी करें और एक टेक्स्ट एडिटर में पेस्ट करें (उदाहरण लॉन्चर बैच स्क्रिप्ट ), उदाहरण के लिए नोटपैड ।
   उदाहरण फ़ाइलें भी संलग्न हैं, इसलिए वैकल्पिक रूप से संलग्न बैच स्क्रिप्ट डाउनलोड करें। .bat फ़ाइल को संपादित करने के लिए, फ़ाइल पर राइट-क्लिक करें और 'संपादित करें' चुनें।
2. स्क्रिप्ट को ध्यान से पढ़ें और जाँचें कि क्या निर्दिष्ट पथ आपकी मशीन पर समान हैं। यदि नहीं, तो उन्हें अपडेट करें ताकि वे सही स्थानों पर इंगित करें।
3. उन उपकरणों से संबंधित अनुभागों को हटा दें जिनका आप उपयोग नहीं करते हैं, उदाहरण के लिए रेंडरर्स या कस्टम स्क्रिप्ट।
4. फ़ाइल को Katana 7.0v1.bat के रूप में सहेजें और बंद करें।
5. अब .bat फ़ाइल पर डबल-क्लिक करें या राइट-क्लिक करें > खोलें , कमांड चलाएँ और सभी आवश्यक पर्यावरण चर सेट के साथ Katana लॉन्च करें।
   
   आप जाँच सकते हैं कि क्या वे सही ढंग से सेट किए गए हैं, उदाहरण के लिए, पायथन टैब में इन कमांडों को चलाकर:
   

   import os
   print(os.environ['KATANA_RESOURCES'])

   
   यह आपके द्वारा लॉन्चर स्क्रिप्ट में KATANA _RESOURCES में जोड़े गए पथों को प्रिंट करेगा।
6. यदि आप डेस्कटॉप आइकन पर क्लिक करके Katana लॉन्च करना चाहते हैं, तो आप इसे निम्नलिखित तरीके से जोड़ सकते हैं:

• .bat फ़ाइल पर राइट-क्लिक करें > शॉर्टकट बनाएं।
• बनाए गए शॉर्टकट को अपने डेस्कटॉप पर रखें।
• शॉर्टकट पर राइट-क्लिक करें > गुण > शॉर्टकट टैब > आइकन बदलें...
• अब आपको एक चेतावनी दिखाई दे सकती है जिसमें लिखा होगा कि .bat फ़ाइल में कोई आइकन नहीं है। ओके पर क्लिक करें और आपको किसी दूसरे स्थान से आइकन चुनने का विकल्प मिलेगा।
• ब्राउज़ करें ... पर क्लिक करें और अपनी Katana इंस्टॉलेशन डायरेक्टरी (KATANA_ROOT) पर जाएँ। WindowsIcon.ico फ़ाइल चुनें और Open पर क्लिक करें। आइकन बदलें डायलॉग बॉक्स बंद करने के लिए OK पर क्लिक करें और Properties विंडो बंद करने के लिए OK पर क्लिक करें।
  
  अब आपके डेस्कटॉप पर Katana आइकन दिखाने वाला Katana लॉन्चर स्क्रिप्ट शॉर्टकट उपलब्ध होगा।

उदाहरण स्क्रिप्ट

निम्नलिखित ड्रॉप-डाउन अनुभागों में सबसे अधिक उपयोग किए जाने वाले प्रत्येक रेंडर प्लग-इन के लिए उदाहरण स्क्रिप्ट प्रदर्शित की गई हैं । ये स्क्रिप्ट उपयोग के लिए तैयार हैं और इन रेंडर प्लग-इन के लिए डिफ़ॉल्ट इंस्टॉलेशन पथों का उपयोग करके कॉन्फ़िगर की गई हैं। आप इस लेख के निचले भाग में "अनुलग्नक " अनुभाग में दिए गए उदाहरण भी डाउनलोड कर सकते हैं।

@echo off
rem -- Define the install location for KATANA --
set "KATANA_ROOT=C:\Program Files\Katana7.0v1"

rem -- select which renderer Katana expects by default when rendering --
set "DEFAULT_RENDERER=prman"

rem -- Location of the RenderMan Pro Server installation --
set "RMANTREE=C:\Program Files\Pixar\RenderManProServer-26.3"

rem -- Location of the PRman plugin for KATANA --
set "RFKTREE=C:\Program Files\Pixar\RenderManForKatana-26.3\plugins\katana7.0"

rem -- This is what is required to load the RfK plugin --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%RFKTREE%"

rem -- These are required for the hdPrman Render Delegate
set "FNPXR_PLUGINPATH=%RFKTREE%\usd"
set "RMAN_SHADERPATH=%RMAN_SHADERPATH%;%RFKTREE%\usd\resources\shaders"
set "RMAN_RIXPLUGINPATH=%RMAN_RIXPLUGINPATH%;%RFKTREE%\usd"

rem -- Start Katana --
"%KATANA_ROOT%\bin\katanaBin.exe"

@echo off
rem -- Define the install location for KATANA --
set "KATANA_ROOT=C:\Program Files\Katana7.0v1"

rem -- select which renderer Katana expects by default when rendering --
set "DEFAULT_RENDERER=arnold"

rem -- Where you have installed the KtoA plug-in --
set "KTOA_HOME=C:\Program Files\ktoa\ktoa-4.3.2.1-kat7.0-windows"

rem -- The KtoA bin folder is needed in PATH --
set "PATH=%PATH%;%KTOA_HOME%\bin"

rem -- This is how to load the KtoA plug-in --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%KTOA_HOME%"

rem -- Start Katana --
"%KATANA_ROOT%\bin\katanaBin.exe"

@echo off
rem -- Define the install location for KATANA --
set "KATANA_ROOT=C:\Program Files\Katana7.0v1"

rem -- select which renderer Katana expects by default when rendering --
set "DEFAULT_RENDERER=dl"

rem -- Location of where the main 3Delight package is installed --
set "DELIGHT=C:\Program Files\3Delight"

rem -- The 3Delight bin folder is needed in PATH  --
set "PATH=%PATH%;%DELIGHT%\bin"

rem -- Location of the 3Delight for KATANA plug-in --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%DELIGHT%\3DelightForKatana"

"%KATANA_ROOT%\bin\katanaBin.exe"

@echo off
rem -- Define the install location for KATANA --
set "KATANA_ROOT=C:\Program Files\Katana7.0v1"

rem -- select which renderer Katana expects by default when rendering --
set "DEFAULT_RENDERER=redshift"

rem -- Location of the RedShift bin folder --
set "REDSHIFT_HOME=C:\ProgramData\Redshift\bin"

rem -- Location of the RedShift plugin for KATANA --
set "REDSHIFT4KATANA_HOME=C:\ProgramData\Redshift\Plugins\Katana\7.0v1"

rem -- This is what is required to load the RedshiftForKatana plugin --
set "PATH=%PATH%;%REDSHIFT_HOME%"
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%REDSHIFT4KATANA_HOME%"

"%KATANA_ROOT%\bin\katanaBin.exe"

उन्नत टिप्स और ट्रिक्स

एकाधिक रेंडरर प्लग-इन

Katana एक ही समय में कई रेंडरर प्लग-इन के साथ लॉन्च करना संभव है। प्रत्येक प्लग-इन के लिए सभी आवश्यक एनवायरनमेंट वैरिएबल को एक बैच फ़ाइल में संयोजित करें और आप Katana में दोनों को एक्सेस कर पाएँगे। हालाँकि, DEFAULT_RENDERER वैरिएबल के लिए केवल एक रेंडरर निर्दिष्ट किया जा सकता है।

कस्टम पर्यावरण चर

अपने स्वयं के कस्टम एनवायरनमेंट वैरिएबल बनाना भी संभव है। अगर आप Katana के कई संस्करणों या किसी विशिष्ट रेंडरर प्लग-इन के बीच तेज़ी से स्विच करना चाहते हैं, तो यह बहुत उपयोगी हो सकता है। नीचे एक RenderMan स्क्रिप्ट का उदाहरण दिया गया है जिसमें OPTIONS हेडर के अंतर्गत तीन कस्टम वैरिएबल बनाए गए हैं। आप देखेंगे कि पथों के कुछ हिस्सों को प्रतिशत चिह्नों से घिरे एनवायरनमेंट वैरिएबल नामों से बदल दिया गया है। यह उस नाम को आपके द्वारा अपनी स्क्रिप्ट में पहले से सेट किए गए मान से बदल देगा।

@echo off
rem **  OPTIONS  **
set "KAT_VER=7.0v1"
set "REN_VER=26.3"
set "KAT_LINE=7.0"

rem -- Define the install location for KATANA --
set "KATANA_ROOT=C:\Program Files\Katana%KAT_VER%"

set "DEFAULT_RENDERER=prman"

rem -- Location of the RenderMan Pro Server installation --
set "RMANTREE=C:\Program Files\Pixar\RenderManProServer-%REN_VER%"

rem -- Location of the PRman plugin for KATANA --
set "RFKTREE=C:\Program Files\Pixar\RenderManForKatana-%REN_VER%\plugins\katana%KAT_LINE%"

rem -- This is what is required to load the RfK plugin --
set "KATANA_RESOURCES=%KATANA_RESOURCES%;%RFKTREE%"

"%KATANA_ROOT%\bin\katanaBin.exe"

अग्रिम पठन

Katana लॉन्च करने और उपलब्ध विभिन्न लॉन्च मोड के बारे में अधिक जानकारी के लिए, कृपया Katana दस्तावेज़ के विंडोज़ पर लॉन्चिंग अनुभाग को देखें।

संलग्नक